Движение, на основе координат точек и скорости

[Tails]

Есть координаты точек А, Б, подопытный - красный шарик и его скорость=5. На основе координат и скорости шарика, нужно как-то высчитывать смещение по x и y, но я не знаю как.

              A x,y
             /
           /
         /
  x,y  B

[StasMIX]

А что такое точки А и Б, начало и конец пути? Тогда зачем скорость? Просто вычтите соответствующие координаты и возьмите модуль.

shiftX=Math.abs(x1-x2);
shiftY=Math.abs(y1-y2);

Хотя это наверно слишком просто, вы что то другое имели в виду?

[Jewelz]

треугольник, sin, cos ?
не очень ясна задача

[samana]

Или вы хотите запустить красный шарик из точки А в точку Б, со скоростью 5?

[Tails]

samana
Да да да.
Извините что неясно выразился, Точка Б это - конец пути, а А - координаты самого шарика.

Добавлено через 7 минут
Нужно двигать к Б, со скоростью 5

[samana]

package 
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Point;
 
	/**
	 * ...
	 * @author Samana
	 */
	public class Main extends Sprite 
	{
		private var redBall:Sprite;
		private var pointB:Point;
		private var speed:Number = 5;
 
		public function Main():void 
		{
			pointB = new Point(400, 500);
 
 
			redBall = new Sprite();
			redBall.graphics.beginFill(0xFF0000);
			redBall.graphics.drawCircle(0, 0, 30);
			redBall.graphics.endFill();
			redBall.x = 150;
			redBall.y = 150;
			addChild(redBall);
 
			addEventListener(Event.ENTER_FRAME, enterFrame);
 
		}
 
		private function enterFrame(e:Event):void 
		{
 
			var dx:Number = pointB.x - redBall.x;
			var dy:Number = pointB.y - redBall.y;
			var dist:Number = Math.sqrt(dx * dx + dy * dy);
 
			if (dist > speed)
			{
				redBall.x += (dx / dist) * speed;
				redBall.y += (dy / dist) * speed;
			}
			else
			{
				redBall.x = pointB.x;
				redBall.y = pointB.y;
				removeEventListener(Event.ENTER_FRAME, enterFrame);
			}
		}
 
	}
 
}

Но удобнее наверно будет использовать TweenMax.

[Vektor]

Вроде так.

var distX=A.x-B.x;
var distY=A.y-B.y;
var dist = Math.sqrt(distX*distX+distY*distY);
var time = dist/speed;
//Получаем скорость по Х и Y.
var mcSpeedX= distX/time;
var mcSpeedY= distY/time;

[Tails]

samana
Vektor
Спасибо, то что нужно.

samana
У тебя даже с демонстрацией

[am_devcorp]

Сообщение от Vektor

Вроде так.

var distX=A.x-B.x;
var distY=A.y-B.y;
var dist = Math.sqrt(distX*distX+distY*distY);
var time = dist/speed;
//Получаем скорость по Х и Y.
var mcSpeedX= distX/time;
var mcSpeedY= distY/time;

Хотя задача и решена, но всё же не лучше ли использовать фичи .geom.Point -a?

 
import flash.geom.Point;
 
var speed:int = 5
var sp:Point =  new Point(B.x - A.x, B.y - A.y)
sp.normalize(speed)
trace(sp.x*sp.x+sp.y*sp.y) // speed^2 = 25
mcSpeedX = sp.x
mcSpeedY = sp.y

И вообще - использовать два намбера для хранения скорости вместо класса вектора(геометрического, ясное дело) - фи-фи-фи, как некрасиво

//случайно пропустил ответ samana, но здесь я делал упор именно на Point.normalize()