задержка на кадре

[rustu]

почему делать задержку на кадре вот таким вот образом не рационально?)

 stop();
    var i_ex_7:Timer = new Timer(30000, 1);
    i_ex_7.start();
    i_ex_7.addEventListener(TimerEvent.TIMER_COMPLETE, function(e:TimerEvent){
        play();
    });

[Aquahawk]

Вполне рационально. Если писать код в кадре. Но писать код в кадре само по себе не рационально и использовать замыкание тоже не хорошо. Лучше создать класс контроллер анимации, или там ещё что-то что управляет вашим клипом. И снаружи стопать когда надо и запускать когда надо. А функцию сделать не анонимной. Тогда это будет вполне хорошо.

[in4core]

Вполне рационально.

Да что вы.
Рационально так

stop();
setTimeout( function():void { play() } , 30000 )

[Aquahawk]

та же болезнь, анонимные функции. Да и сеттаймаут это ни чуть не лучше таймера.

[КорДум]

setTimeout(play, 30000);

Тогда уж так. Без анонимности, но используя обертку над таймером.

[in4core]

КорДум - я ж написал общий пример, ведь кроме плей там может быть еще что.

та же болезнь, анонимные функции. Да и сеттаймаут это ни чуть не лучше таймера.

Да что вы? Откуда такие познания, что сеттаймаут не лучше? А я вам скажу, операция сеттаймаут будет в разы быстрее , чем создание таймера, подписка на событие, которое кстати не забыть бы удалить еще. В данном случае анонимная ( на самом деле анонимная это другое ) функция оправдана вполне, ведь методы такого плана смогут хоть немного нагрузить систему в случае если будут описаны в каждом кадре каждого клипа, да и то не факт

собственно проведите хотя бы тесты , ради приличия :

for( var i:int = 0 ; i < 1000000 ; i++)  setTimeout( function():void { play() } , 30000 )
for (var j:int = 0 ; j < 1000000 ; j++) var t:Timer = new Timer(30000,1) , t.addEventListener(TimerEvent.TIMER , onTime)

Как просчитать разность думаю знаете

[Aquahawk]

in4core без комментариев.

Добавлено через 16 минут

package 
{
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.TimerEvent;
	import flash.utils.getTimer;
	import flash.utils.setTimeout;
	import flash.utils.Timer;
 
	/**
	 * ...
	 * @author Aquah
	 */
	public class Main extends MovieClip 
	{
 
		public function Main():void 
		{
			trace(getTimer());
			for ( var i:int = 0 ; i < 1000000 ; i++)  setTimeout( function():void { play() } , 30000 );
			trace(getTimer());
			for (var j:int = 0 ; j < 1000000 ; j++)
			{
				var t:Timer = new Timer(30000, 1);
				t.addEventListener(TimerEvent.TIMER , onTime)
			}
			trace(getTimer());
		}
 
		public function onTime(evt:TimerEvent):void
		{
 
		}
	}
}

582
16353
20241

В следующий раз попрошу использовать менее резкий тон и самостоятельно тестировать код который предлагаете тестировать другим

[in4core]

Тьфу блин, и правда. извиняюсь. Чтож они там внутри такое сделали что аж 16 секунд (( Хотя на 10000 итераций почти одинаковая скорость, да и на 100000 близки...

[Aquahawk]

А то что анонимные функции зло уже столько раз обсуждали что даже лень вообще что либо из аргументов приводить.

[in4core]

А то что анонимные функции зло уже столько раз обсуждали что даже лень вообще что либо из аргументов приводить.

Это не анонимная функция !! Ну дело даже не в этом, тормозит сам сеттаймаут , пример выше который описал Кордум, работает так же по скорости