Как добавить данные из XML в List и ComboBox

[alexandrratush]

Я смотрю тут много собралось народа помочь.
Вот набросал вам пример как примерно все должно быть, разбирайтесь.

import flash.events.Event;
 
var myLoader: URLLoader = new URLLoader();
myLoader.load(new URLRequest("xmls/list_themes_words.xml"));
myLoader.addEventListener(Event.COMPLETE, loaded);
 
function loaded (event: Event)
{
	var myxml:XML = XML(event.target.data);
 
	var item:XML;
	var name:String;
	var data:XMLList;
	for each (item in myxml.Themes.theme)
	{ 
		name = item.@themeTitle;
		data = item.videoWord;
 
		comboBox.addItem({label: name, data:data});
	}
 
	comboBox.addEventListener(Event.CHANGE, changeCB);
}
 
function changeCB(e:Event):void
{
	var data:XMLList = comboBox.selectedItem.data;
 
	list.removeAll();
 
	var item:XML;
	var name:String;
	var url:String;
	for each (item in data)
	{ 
		name = item.@videoTitle;
		url = item.@videoFile;
 
		list.addItem({label: name, data: url});
	} 
 
	list.addEventListener(Event.CHANGE, changeList);
}
 
function changeList(e:Event):void
{
	trace(list.selectedItem.data);
}