Как разделить события перетаскивания и клика по одному мувику?

[dimka_boy]

Сообщение от Gogan

Да, снова поспешил я, наверное не оттуда скопировал...
Удалить нужно эту вот строку:

hero.removeEventListener(MouseEvent.CLICK, heroClick);

Огромное спасибо! Очень помогли!)

[Zebestov]

Приведенный выше код будет наказывать "кликом" за малейшее смещение.
Присоединяюсь к решению с детектором модуля смещения по любой из осей. Он работает всегда четко и однозначно. Решение с задержкой по времени мне в свое время показалось неким костылем.

import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.events.Event;
 
// Создаем объект, который будем кликать/таскать.
var o:Sprite = new Sprite();
o.graphics.beginFill(0xff0000);
o.graphics.drawCircle(0, 0, 30);
o.graphics.endFill();
o.x = stage.stageWidth / 2;
o.y = stage.stageHeight / 2;
addChild(o);
 
// Готовимся отделять мух от... клики от перетаскивания.
// Задаем порог, после которого клик становится перетаскиванием.
const THRESHOLD:int = 5;
// Точка, в которой нажали кнопку мыши.
var startX:int;
var startY:int;
// Флаг, указывающий на то, что происходит перетаскивание.
var dragFlag:Boolean;
 
// Добавляем слушатель нажатия мыши на объекте.
o.addEventListener(MouseEvent.MOUSE_DOWN, handlerMouseDown);
 
// Нажали кнопку, началось.
function handlerMouseDown(event:MouseEvent):void
{
	o.addEventListener(MouseEvent.MOUSE_MOVE, handlerMouseMove);
	o.stage.addEventListener(MouseEvent.MOUSE_UP, handlerMouseUp);
	o.stage.addEventListener(MouseEvent.MOUSE_OUT, handlerMouseOut);
 
	startX = event.stageX;
	startY = event.stageY;
	dragFlag = false;
}
 
// Двигаем мышкой.
function handlerMouseMove(event:MouseEvent):void
{
	var dx:int = Math.abs(event.stageX - startX);
	var dy:int = Math.abs(event.stageY - startY);
 
	if (!dragFlag && (dx > THRESHOLD || dy > THRESHOLD))
	{
		dragFlag = true;
		o.startDrag();
	}
}
 
// Все закончилось из-за того, что отжали кнопку мыши.
function handlerMouseUp(event:MouseEvent):void
{
	finish();
}
 
// Все закончилось из-за того, что мышь ушла со сцены.
function handlerMouseOut(event:MouseEvent):void
{
	finish();
}
 
// А заканчивать все будем здесь.
function finish():void
{
	o.removeEventListener(MouseEvent.MOUSE_MOVE, handlerMouseMove);
	o.stage.removeEventListener(MouseEvent.MOUSE_UP, handlerMouseUp);
	o.stage.removeEventListener(MouseEvent.MOUSE_OUT, handlerMouseOut);
 
	if (dragFlag)
	{
		o.stopDrag();
	}
	else
	{
		trace("CLICK!");
	}
}