Свой attachMovie, нужен совет

[_steF]

Больно не пинайте...
Вот наваял свой attachMovie:

function AttachMovie(Lincage:Object, NewName:String, At:Number, _Xx:Number, _Yy:Number, parentMc:Object):Object{
	var ChildMc:Object = Lincage;
	ChildMc.name = NewName;
	parentMc.addChild(ChildMc);
	ChildMc.x = _Xx;
	ChildMc.y = _Yy;
	return parentMc.getChildByName(NewName);
}
 
for(var i=0;i<5;i++){
	var mcItem:MovieClip = AttachMovie( new baseMс(), "ini_"+i, i, 10, i*60, this);
	mcItem.buttonMode = true;
	.........
}

Работает.
Чем опасен етот код?

[etc]

Код безумный.

[mre]

А зачем возвращать через getChildByName?
Переменная At не используется и по-хорошему типа int должна быть.
Именование и типизация переменных оставляет желать лучшего.
Вместо Object используйте DisplayObject и DisplayObjectContainer.

Это для начала.

[_steF]

Сообщение от __etc

Код безумный.

У меня в старом проэкте очень много используется attachMovie. Пытаюсь минимзировать кодинг.

[iNils]

У вас должно быть примерно так

function attachMovie (linkage:DisplayObject, x:Number, y:Number, parentMc:DisplayObjectContainer):DisplayObject {
	linkage.x = x;
	linkage.y = y;
	parentMc.addChild (linkage);
	return linkage;
}
 
for (var i=0; i<5; i++){
	var mcItem:MovieClip = attachMovie (new baseMс (), 10, i * 60, this) as MovieClip;
	mcItem.buttonMode = true;
	.........
}

[etc]

Можно так:

function attachMovie (linkage:DisplayObject, x:Number, y:Number, parentMc:DisplayObjectContainer):DisplayObject {
	linkage.x = x;
	linkage.y = y;
	return parentMc.addChild(linkage);
}

[Nirth]

function attachMovie(movie:DisplayObject, container:DisplayObjectContainer, init:Object = null):DisplayObject
{
        var result:DisplayObject = container.addChild(movie);
 
	if(init)
        {
		for(var propertyName:String in init)
                {
                        try
                        {
			        result[propertyName] = init[propertyName];
                        }
                        catch(e:Error)
                        {
                                trace('You Bloody Moron, there is no such property, motherfucker!');
                        }
                 }
        }	
	return result;
}

И вот еще тебе createEmptyDisplayObject

function createEmptyDisplayObject(container:DisplayObjectContainer, generator:Class = null):DisplayObject
{
    if(generator == null)
        generator = flash.display.Sprite;
    return container.addChild(new generator());
}

[silin]

если уж дословно, то

public function attachMovie(id:String, name:String, depth:Number, initObject:Object) : MovieClip 
{
	var res:MovieClip;
	var cl:Class = getDefinitionByName(id) as Class;
	try
	{
		res = MovieClip(this.addChildAt(new cl(), int(depth)));
                res.name = name;
		for ( var param:String in initObject)
		{
			res[param] = initObject[param];
		}
	}catch(err:Error){}
 
	return res;
}

бредовые затеи..
телТаржетов у вас в проекте не используется случаем ?, а то давайте и их сюда подтянем..

[Nirth]

Кстати, через Proxy можно еще и slash нотацию попробывать=)

[_steF]

Пасибо всем!!!!
Не одному мне помогли, я думаю ...

танкс