setInterval не срабатывает при добавлении в onRollOver

[Emz]

К объекту obj1_mc на сцене (обычный мувик-квадрат) программно добавляется свечение, которое постепенно усиливается с помощью setInterval. Но как только intervalId добавляешь в onRollOver - перестает срабатывать функция (см. в самом конце кода). Не могу разобраться, в чем может быть причина.

//подключение  фильтров
import flash.filters.BitmapFilter;
import flash.filters.GradientGlowFilter;
 
// задаем параметры свечения
var distance:Number = 0;// Смещение свечения
var angleInDegrees:Number = 45;// Угол поворота
var colors:Array = [0xFFFF99, 0xFFFFFF];// Массив цветов
var alphas:Array = [0, 1];// Массив прозрачностей для цветов
var ratios:Array = [0, 255];// Позиции цветов от 0 до 255
var blurX:Number = 50;// Блюр по Х от 0 до 255
var blurY:Number = 50;// Блюр по У от 0 до 255
var strength:Number = 0;// Интенсивность от 0 до 255   //Этот параметр будем изменять
var quality:Number = 5;// Качество от 0 до 15
var type:String = "outer";// Тип
var knockout:Boolean = false;// Скрыть обьект или нет
 
//функция добавления свечения
//varTarget - "освечивающийся" мувик, в данном случае  obj1_mc
 
function addGradientGlow(varTarget):Void
{
	varTarget.filters = [new GradientGlowFilter(distance, angleInDegrees, colors, alphas, ratios, blurX, blurY, strength, quality, type, knockout)];
 
	if (strength>2)
	{
		clearInterval(intervalId);
	} else
	{
		strength += 0.03;
	}
}
 
//_root.obj1_mc.onRollOver = function ():Void { //!!! Проблема здесь
intervalId = setInterval(this, "addGradientGlow", 20, _root.obj1_mc); //постепенное увеличение свечения мувика obj1_mc через каждые 20мсек
// } //конец проблемы

[udaaff]

Область видимости потому-что меняется, и this уже указывает на _root.obj1_mc.

[Emz]

тогда как сделать, чтобы setInterval повторяло само себя?

intervalId = setInterval(intervalId, "addGradientGlow", 20, _root.obj1_mc);

так тоже не работает

[mooncar]

_root.obj1_mc.onRollOver = function ():Void { 
	intervalId = setInterval(addGradientGlow, 20, this);
}

Синтаксис функции:

setInterval(functionReference:Function, interval:Number, [param1:Object, param2, ..., paramN]) : Number

[Emz]

Благодарствую!
setInterval у меня больное место, всегда об него спотыкаюсь в каком-нибудь месте