Странное поведение split(), join() и преобразования типов

[HraD]

Есть код:

package
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	/**
	 * ...
	 * @author HraD
	 */
	public class Main extends Sprite
	{
		private var array1:Array = [0,0,0,0,100,0,200,0,145,0];
		private var array2:Array = [];
 
		public function Main():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
			var string1:String = array1.join(";");
			trace("string1", string1);
			array2 = string1.split(";");
			trace("array2", array2);
			var summa:int = 0;
			for (var i:int = 0; i < array2.length; i++)
			{
				summa += array2[i];
				trace("Сумма:", summa, "array2[i] is Object", array2[i] is Object, "summa is int", summa is int);
			}
		}
	}
}

В трейсе будет следующее:

[Capturing traces with FDB]
string1 0;0;0;0;100;0;200;0;145;0
array2 0,0,0,0,100,0,200,0,145,0
Сумма: 0 array2[i] is Object true summa is int true
Сумма: 0 array2[i] is Object true summa is int true
Сумма: 0 array2[i] is Object true summa is int true
Сумма: 0 array2[i] is Object true summa is int true
Сумма: 100 array2[i] is Object true summa is int true
Сумма: 1000 array2[i] is Object true summa is int true
Сумма: 1000200 array2[i] is Object true summa is int true
Сумма: 10002000 array2[i] is Object true summa is int true
Сумма: 1412065553 array2[i] is Object true summa is int true
Сумма: 1235753642 array2[i] is Object true summa is int true

Соответственно вопрос, почему флэш делает это так?

[Rzer]

Правильно:

summa += int(array2[i]);

Иначе флеш делает так:

summa  = summa  + array2[i];

array2[i] - строка, значит мы хотим объеденить две строки в одну. Меняем тип сумма на String автоматом и соединяем. Затем идёт присваивание. Присваиваем числу значит пробуем перевести получившуюся строку в число. (строка 00000 переводится в 0)

[udaaff]

summa += array2[i]; это тоже самое, что и summa = summa + array2[i].
array2[i] содержит строки, соответственно результат вычисления правой части выражения будет строкой. Далее это строка преобразовывается в int.
В двух последних итерациях int "обрезает" число до 32 разрядов.

Сумма: 1412065553 array2[i] is Object true summa is int true
Сумма: 1235753642 array2[i] is Object true summa is int true

[HraD]

Сообщение от Rzer

Правильно:

summa += int(array2[i]);

Так и сделал в итоге. Всем спасибо, просто некоторые моменты типа

В двух последних итерациях int "обрезает" число до 32 разрядов.

несколько не очевидны...