AS-алхимия: обработка события с доп. параметрами.

[iNils]

Kikasso, так у нас же область видимости тогда не меняется. Как были внутри кнопки, так в ней и остались.

[WindWalker]

Сообщение от iNils

Это то, ради чего вы это все затеяли?

Да. И в первом сообщении я довольно подробно это объяснил.

Kikasso
У вас this получается Button.

[iNils]

Сообщение от WindWalker

Да. И в первом сообщении я довольно подробно это объяснил.

Не может я чего то не понял. А так вы изобрели велосипед, только колеса у вас квадратные.

[WindWalker]

Нет, мой велосипед выглядит вот так:

static function delegate(obj: Object, func: Function):Function {
       var f = function() {
            var target = arguments.callee.target;
            var func = arguments.callee.func;
            return func.apply(target, arguments.concat(arguments.callee.args));
        };
        f.target = obj;
        f.func = func;
        f.args = arguments.slice(2);
        return f;
}

На нём и катался последние два-три года.

А класс Call - это чистая магия

[iNils]

WindWalker, есть один такой здоровый минус. Когда я пользуюсь в FlashDevelop своим Delegate, там у меня работает автокомплит. И здесь его не будет.

[Kikasso]

Зачем нам колдовать с областью видимости? Мы можем передать ее параметром, а уж что за функция будет "на приеме", другое дело:

function onMenuReleased(){
	var arr = arguments;
return ( function(){ trace("hello from " + this._name); trace( "arguments: " + arr); } );
}
btnMenu1.onRelease = onMenuReleased(1);
btnMenu2.onRelease = onMenuReleased(2);
btnMenu3.onRelease = onMenuReleased(this, 3, 4);

И наконец, почему бы новичкам не научиться писать нормально?

function onMenuReleased(){
	trace("hello from " + this);
	trace( arguments.length ?  ("arguments: " + arguments.join(", ") ) : "no arguments" );
}
btnMenu1.onRelease = onMenuReleased;
btnMenu2.onRelease = function(){ onMenuReleased(2); }
btnMenu3.onRelease = function(){ onMenuReleased(this, 3, 4); }
btnMenu4.onRelease = function(){ onMenuReleased(); }

[etc]

Область видимости не должна меняться.

[WindWalker]

Сообщение от Kikasso

И наконец, почему бы новичкам не научиться писать нормально?

function onMenuReleased(){
	trace("hello from " + this);
	trace( arguments.length ?  ("arguments: " + arguments.join(", ") ) : "no arguments" );
}
btnMenu1.onRelease = onMenuReleased;
btnMenu2.onRelease = function(){ onMenuReleased(2); }
btnMenu3.onRelease = function(){ onMenuReleased(this, 3, 4); }
btnMenu4.onRelease = function(){ onMenuReleased(); }

Тут крайне неоднозначно будет с видимостями.

Сделал я 4 кнопочки, поместил этот код в кадр.
Затем запустил и поочередно щёлкнул по каждой кнопке.
И вот что я получил:

hello from _level0.btnMenu1
no arguments
hello from _level0
arguments: 2
hello from _level0
arguments: _level0.btnMenu3, 3, 4
hello from _level0
no arguments

Что вполне логично.
В первом случае onMenuReleased вызвалось от имени кнопки.
Во всех остальных случаях неявно подставился _root.

Затем я объединил все кнопки в один мувик и привязал к этому мувику вот такой вот класс:

class Menu extends MovieClip {
  var btnMenu1:Button;
  var btnMenu2:Button;
  var btnMenu3:Button;
  var btnMenu4:Button;

  function onMenuReleased(){
    trace("hello from " + this);
    trace( arguments.length ?  ("arguments: " + arguments.join(", ") ) : "no arguments" );
  }

  function Menu() {
    btnMenu1.onRelease = onMenuReleased;
    btnMenu2.onRelease = function(){ onMenuReleased(2); }
    btnMenu3.onRelease = function(){ onMenuReleased(this, 3, 4); }
    btnMenu4.onRelease = function(){ onMenuReleased(); }
  }
}

Т.е. практически тоже самое.
Однако теперь работает только первая кнопка (и опять же this будет кнопка, а не наш класс).
Во всех остальных случаях он не может найти onMenuReleased.


Вот как раз из-за таких проблем с областью видимости и придумали класс mx.utils.Delegate, который каждый переделывает на свой лад.

[etc]

Не надо объявлять методов в методах, от этого только проблемы возникнут. А в Delegate лучше не смотреть, работает и работает. Это костыль в AS2, без него никуда, увы.

[Kikasso]

Сообщение от WindWalker

Во всех остальных случаях он не может найти onMenuReleased

Конечно, он не может его найти. this в этот момент вообще не пойми что, btnOnRelease тоже как таковой нет, а вы создаете метод с ее участием.
Если объявлять эту btnOnrelease в конструкторе, это сработает, но без ссылки на самого себя не обойтись.
Только такой изврат извратович:

class Menu extends MovieClip {
  var btnMenu1:Button;
  var btnMenu2:Button;
  var btnMenu3:Button;
  var btnMenu4:Button;
  function onMenuReleased():Void{
  	trace("hello from " + this);
    trace( arguments.length ?  ("arguments: " + arguments.join(", ") ) : "no arguments" );
  }
  function Menu() {
  	var viz:Menu = this;
    btnMenu1.onRelease = onMenuReleased;
    btnMenu2.onRelease = function(){ viz.onMenuReleased(2); }
    btnMenu3.onRelease = function(){ viz.onMenuReleased(this, 3, 4); }
    btnMenu4.onRelease = function(){ viz.onMenuReleased(); }
  }
}

Жуть.
__etc прав, не надо мудрить.
А если без классов, в кадре - проблем нет.