Вопрос по циклической загрузке клипов в рандомном порядке. Возможно ли?

[storm_]

Дорогие флешеры.
Вновь фрилансерская судьба преподнесла вопрос, который я не в состоянии решить сам.
Ситуация такая:

Stage.scaleMode = "noscale";
var w = new XML();
all._visible = false;
//LINKS
w.load("links.xml");
w.ignoreWhite = true;
w.onLoad = function() {
	col = this.firstChild.childNodes[0].attributes.number;
	min = 20;
//Создан циклический загрузчик, который по очереди загружает нужное 
//кол-во изображений в сгеннерированные мувики.
	for (i=0; i<col; i++) {
		var k_mc:MovieClip = all.createEmptyMovieClip("k"+i, i);
//Тут генерятся пустышки, на которые будут вешаться ссылки:
		var l_mc:MovieClip = all.l.duplicateMovieClip("l"+i, 200+i);
//Берется для конкретной пустышки, конкретная ссылка из хмл
		l_mc.link = this.firstChild.childNodes[1+i].attributes["logo"+i];
//Присваивается…
		l_mc.onRelease = function() {
			getURL(this.link, "_blank");
		};
//loader
		var mc0Listener:Object = new Object();
		var p0:MovieClipLoader = new MovieClipLoader();
		p0.addListener(mc0Listener);
		p0.loadClip(i+".png", all["k"+i]);
	}
	mc0Listener.onLoadInit = function() {
//После окончания загрузки
		dl = 0;
		all.k0._x = 0;
		for (b=0; b<col; b++) {
			dl += all["k"+b]._width+60;
			bb = 1;
			bb += b;
//Клипы выстраиваются исходя из их ширины один за другим.
			all["l"+b]._width = all["k"+b]._width;
			all["k"+b]._y = (100-all["k"+b]._height)/2;
			all["k"+bb]._x = dl;
			all["l"+b]._y = (100-all["k"+b]._height)/2;
			all["l"+bb]._x = dl;
		}
		max = r-dl;
		all._visible = true;
	};

Вот. Сейчас все грузится последовательно и расставляется соответственно последовательно — один за другим, как кирпичеки.

Вот вопрос:
Заказчик хочет, чтобы клипы каждый раз грузились рандомно. Как осуществить это? К примеру, в папке лежит 50 клипов, их все нужно загрузить на одну горизонталь, и расставить их все в перемешку.
Как быть?

[Wolsh]

Ну так перемешайте массив childNodes перед загрузкой.

[storm_]

Wolsh, большое спасибо. Не покажите как именно это сделать?

[scarbo]

Wolsh это тут уже делал,поишите в его сообщениях

[storm_]

scarbo, спасибо конечно за совет. Но у Wolsh всего 1729 сообщений .
Wolsh, отзовитесь пожалуйста.

[Wolsh]

var tempArr:Array = this.firstChild.childNodes.concat();
var piclength:Number = tempArr.length;
var randomNodes:Array = [];
for(var i = 0; i < piclength; i++)
{
    var q:Number = Math.floor(Math.random()*(tempArr.length-1));
    randomNodes.push(tempArr[q]);
    tempArr.splice(q, 1);
}
trace(randomNodes)

[storm_]

Wolsh, Спасибо огромное! Выручаете не первый раз!

[Wolsh]

А, блин, косяк нашел - последний остается всегда последним.
Правильно вот так

var tempArr:Array = this.firstChild.childNodes.concat();
var piclength:Number = tempArr.length;
var randomNodes:Array = [];
for(var i = 0; i < piclength; i++)
{
    var q:Number = Math.floor(Math.random()*(tempArr.length));
    randomNodes.push(tempArr[q]);
    tempArr.splice(q, 1);
}
trace(randomNodes)