Подскажите код запуска видео по клику мышки...

[grumbler0]

Уважаемые флэшеделы подскажите, пожалуйста.
Нужен такой код, что бы нарисованный клип во Flash,( в формате SWF, потом)сначала не проигрывался, а на экране была видна картинка (с первого кадра временной шкалы) и лишь после клика мышки по экрану клип начинал проигрываться...
Спасибо.

[fish_r]

Это вам нужно?
Или имеется в виду какой то FLV-компонент?

package
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	public class Main extends MovieClip
	{
 
 
 
		/**
		 *  Конструктор.
		 */
		public function Main()
		{
 
			if (stage) init(null);
			else this.addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
 
		/**
		 * Инициализация.
		 * @param	e
		 */
		private function init(e:Event):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
 
			this.stop();
			_myClip.stop();
			/**
			 *  Что бы сам, непосредственно, клик не принимал.
			 */
			_myClip.mouseChildren = false;
 
			stage.addEventListener(MouseEvent.CLICK, playClipListener);
		}
 
 
		/**
		 *  Запускает клип по клику мыши
		 * @param	e
		 */
		private function playClipListener(e:MouseEvent):void 
		{
			stage.removeEventListener(MouseEvent.CLICK, playClipListener);
			/**
			 * Если хотите запустить клип лежащий на сцене его instance name
			 * надо дать имя _myClip. При этом должна быть установлена галочка
			 * по пути: Publish Settings->Flash->Settings->Automatically declare 
			 * stage instances . 
			 */
 
			_myClip.play();
 
			/**
			 * Если нужно запустить не клип лежащий на сцене, а в том случае
			 * если сама сцена является клипом.
			 */
			this.play();
			stage.addEventListener(MouseEvent.CLICK, stopClipListener);
		}
 
		/**
		 * Останавливает клип по клику мыши. Опять
		 * ждет клика для запуска.
		 * @param	e
		 */
		private function stopClipListener(e:MouseEvent):void 
		{
			stage.removeEventListener(MouseEvent.CLICK, stopClipListener);
			_myClip.stop();
			this.stop();
			stage.addEventListener(MouseEvent.CLICK, playClipListener);
		}
	}
}

Во вложении пример реализации.

[bav]

_myClip.mouseChildren = false;

[fish_r]

Сообщение от bav

_myClip.mouseChildren = false;

ес! ес!