Вывести flashVars на экран

[Srednas]

Здравствуйте.

Подскажите как вывести все flashVars на экран?
Не катит:

trace(stage.loaderInfo.parameters);

Наверняка нужно в цикле, но что-то туплю

[Psycho Tiger]

Это один из классов, который был написан мной очень давно, но используется без внесения каких-либо правок.

package artshlagin.utils
{
	/**
	 * ...
	 * @author Artem Shlagin
	 */
	public class Tracer {
		public static var traceFunction:Function = trace;
		public static var nameDelimiter:String = " => ";
		public function Tracer() {
			throw new Error("Class is static");
		}
 
		public static function fullTraceObject(object:Object):void {
			recoursiveTrace(object);
		}
 
		private static function recoursiveTrace(o:Object, startValue:int = 0):void {
			for (var name:Object in o) {
				var otst:String = "";
				if (startValue > 0) {
					var i:int = startValue;
					while (i--) otst += "     ";
				}
				traceFunction.call(null, otst + name + nameDelimiter + o[name]);
				if ((typeof o[name]) === "object") recoursiveTrace(o[name], startValue+1);
			}
 
		}
 
 
	}
}

Использовать:

Tracer.fullTraceObject(stage.loaderInfo.parameters);

Можно менять поток вывода и стрелочку между ключом и значением )

Tracer.traceFunction = _someTextField.appendText;
Tracer.nameDelimiter = "<->";

[Bgg]

Почитайте про режим удаленной отладки(remote debug). Так же можете попробовать MonsterDebugger.

[strangedk]

Просто можно сделать так:

public var _txt:TextField;
 
function _traceFlashVars() {
	_txt.appendText("init \n");
 
	for each (var current in stage.loaderInfo.parameters) {
		_txt.appendText(current + "\n");
	}
}

где _txt - добавленный на сцену TextField;