Клавиатура работает не так как я ХОЧУ (тест не проходит)

[Evgeny_Flash_8]

Продолжение темы: Переход по кадрам (клавиатурой)
http://www.flasher.ru/forum/showthread.php?t=119432

Доброе утро! Простите, что я создаю новую тему с тем же вопросом. Просто я не получил ответа, а тема моя оказалась уже на 3 вкладке. Надеюсь сейчас получу ответ.
Тут ведь светлые умы России (а может даже и СНГ) по флэшу

stop();
//строгая типизация переменной
var i:Number = _currentframe;				// первый кадр
var j:Number = _totalframes;				// последний кадр

//определяем функцию goNextFrame()
function goNextFrame() {
	if (i<j) {
		nextFrame();
		i = i + 1;
	}
}

//определяем функцию goPrevFrame()
function goPrevFrame() {
	if (i>1) {
	prevFrame();
	i = i - 1;
	}
}

var keyListener_obj:Object = new Object();
keyListener_obj.onKeyDown = function() {
	switch (Key.getCode()) {
	case Key.SPACE :
		goNextFrame();
		break;
	case Key.LEFT :
		goPrevFrame();
		break;
	case Key.RIGHT :
		goNextFrame();
		break;
	}
}
Key.addListener(keyListener_obj);

//назначаем ссылку на функцию обработчику событий кнопки onPress
next_btn.onPress = goNextFrame;

//назначаем ссылку на функцию обработчику событий кнопки onPress
prev_btn.onPress = goPrevFrame;

Можете запустить *.swf файл и ввести одну из следующих комбинаций на клавиатуре.
←→←→←→←→←→←→ и можете продолжать дальше
или
←←→→←←→→←←→→ и можете продолжать дальше
в итоге вы будете видеть только 1 и последний кадр.

Как сделать, чтобы клавиатура работала!
Нет она у меня работает, т.к. я пишу, но в проге она не делает что я хочу.
Я так думаю, что я в коде допустил ошибку.

Заранее спасибо за ответ!!!

[KiL33]

stop();
if (init == undefined) {
 someListener = new Object();
 someListener.onKeyDown = function() {
 if (Key.isDown(Key.LEFT) || Key.isDown(Key.UP)) {
 _level0.prevFrame();
 } else if (Key.isDown(Key.RIGHT) || Key.isDown(Key.DOWN)) {
 _level0.nextFrame();
 }
 };
 Key.addListener(someListener);
 init = 1;
}
 
//определяем функцию goNextFrame()
function goNextFrame() {
_level0.nextFrame();
}
//определяем функцию goPrevFrame()
function goPrevFrame() {
_level0.prevFrame();
}
 
//назначаем ссылку на функцию обработчику событий кнопки onPress
next_btn.onPress = goNextFrame;
 
//назначаем ссылку на функцию обработчику событий кнопки onPress
prev_btn.onPress = goPrevFrame;

[Evgeny_Flash_8]

Спасибо, теперь все работает!!!

Я задам 2 глупых вопроса:
1, почему тот метод не работает?
2. объясните пожалуйста, что во 2 коде?

[alexcon314]

Ваш метод работает, если не делать лишнего:

stop();
//строгая типизация переменной
var i:Number = _currentframe;
// первый кадр
var j:Number = _totalframes;
// последний кадр
//определяем функцию goNextFrame()
function goNextFrame() {
	if (i<j) {
		nextFrame();
		i = i+1;
	}
}
//определяем функцию goPrevFrame()
function goPrevFrame() {
	if (i>1) {
		prevFrame();
		i = i-1;
	}
}
onKeyDown = function () {
	switch (Key.getCode()) {
	case Key.SPACE :
		goNextFrame();
		break;
	case Key.LEFT :
		goPrevFrame();
		break;
	case Key.RIGHT :
		goNextFrame();
		break;
	}
};
Key.addListener(this);
//назначаем ссылку на функцию обработчику событий кнопки onPress
next_btn.onPress = goNextFrame;
//назначаем ссылку на функцию обработчику событий кнопки onPress
prev_btn.onPress = goPrevFrame;

или вообще без лишнего:

stop();
prev_btn.onPress = function() {
	prevFrame();
};
next_btn.onPress = function() {
	nextFrame();
};
onKeyDown = function (btn) {
	switch (Key.getCode()) {
	case Key.SPACE :
		nextFrame();
		break;
	case Key.LEFT :
		prevFrame();
		break;
	case Key.RIGHT :
		nextFrame();
		break;
	}
};
Key.addListener(this);

А не работало у вас потому, что при попадании на первый кадр код в нем заново исполнялся и инициализировался еще один лишний объект-слушатель событий клавиатуры. Проверить нетрудно:

case Key.LEFT :
	trace(Key._listeners.length);
	goPrevFrame();
	break;
case Key.RIGHT :
	trace(Key._listeners.length);
	goNextFrame();
	break;

Трэйс выводит, что массив листенеров событий объекта Key, пополняется каждый раз, когда попадаем на первый кадр. По нажатию на кнопку событие получали все объекты разом и мотали каждый пленку вперед/назад. Можете убедиться сами. Просто добавьте в ваш код на первом кадре

Key.removeListener(keyListener_obj);

и все заработает.

Код из пердыдущего поста как раз посвоему решал эту проблему. Тут тоже создается совершенно ненужный объект-листенер, но только один раз по флагу init, на счастье, видимо.

if (init == undefined) {
someListener = new Object();
someListener.onKeyDown = function() {
if (Key.isDown(Key.LEFT) || Key.isDown(Key.UP)) {
_level0.prevFrame();
} else if (Key.isDown(Key.RIGHT) || Key.isDown(Key.DOWN)) {
_level0.nextFrame();
}
};
Key.addListener(someListener);
init = 1;
}

[KiL33]

Это был пример из хэлпа))

[Evgeny_Flash_8]

Спасибо большое за объяснение!