Как проверить нажата ли кнопка мыши?

[wolhw]

Сопственно после срабатывания MouseEvent.MOUSE_DOWN нужно проверить нажата ли все еще кнопка и повторять действие с заданым интервалом если нажата(нетрогая причем MouseEvent.MOUSE_OUT/UP) .
???

[GBee]

нетрогая причем MouseEvent.MOUSE_OUT/UP

Чем вас не устраивает то, от чего вы отказываетесь?

[goodguy]

Есть специальный класс Key

package  {
 
	import flash.display.Stage;
	import flash.display.StageDisplayState;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import flash.geom.Rectangle;
 
	public class Key {
 
		private static var initialized:Boolean = false;		
		private static var keysDown:Object = new Object();	
 
		public static function initialize(stage:Stage):void {
			if (!initialized) {
				stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressed);
				stage.addEventListener(KeyboardEvent.KEY_UP, keyReleased);
				stage.addEventListener(Event.DEACTIVATE, clearKeys);
				initialized = true;
			}
		}
 
		public static function isDown(keyCode:uint):Boolean {
			if (!initialized) {
				throw new Error("Key class has yet been initialized.");
			}
			return Boolean(keyCode in keysDown);
		}
		private static function keyPressed(event:KeyboardEvent):void {
			keysDown[event.keyCode] = true;
		}
		private static function keyReleased(event:KeyboardEvent):void {
			if (event.keyCode in keysDown) {
				delete keysDown[event.keyCode];
			}
		}
		private static function clearKeys(event:Event):void {
			keysDown = new Object();
		}
	}
}

Инициализируем, передав в конструкторе stage

Key.initialize(stage);

после в любое время проверяем нажата ли какая-нибудь клавиша:

if (Key.isDown(Keyboard.SPACE)) {
    trace("нажат пробел");
}

[kackbip]

Кажется все таки о мышке речь была.

[dimarik]

kackbip, ну выходные же все-таки )

[goodguy]

kackbip, ну выходные же все-таки )

Точно Загон зашел, что о клавиатуре )
Мозг в нирване

п.с. Ну по тому же принципу можно и мышь проверять. Так же создать статический класс и ставить при нажатии какую-то переменную true, при отпускании false

package  {
 
	import flash.display.Stage;
	import flash.events.MouseEvent;
 
	public class MouseButton {
 
		private static var initialized:Boolean = false;		
		private static var mouseDown:Boolean = false;	
 
		public static function initialize(stage:Stage):void {
			if (!initialized) {
				stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
				stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);
				initialized = true;
			}
		}
 
		public static function isDown():Boolean {
			if (!initialized) {
				throw new Error("MouseButton class has yet been initialized.");
			}
			return mouseDown;
		}
		private static function onMouseDown(event:MouseEvent):void {
			mouseDown = true;
		}
		private static function onMouseUp(event:MouseEvent):void {
			mouseDown = false;
		}
	}
}

[dimarik]

has not yet been initialized [x]

[goodguy]

has not been initialized yet =)
если уж быть точнее )
Но эту строчку писал не я

[wolhw]

Сообщение от GBee

Чем вас не устраивает то, от чего вы отказываетесь?

хотелось предвидеть возможность таскать курсор с зажатой клавишей по разным мувикам...

goodguy спасибо за примеры, пригодитса.

И есче вопрос касающийся мыши-- можно ли каким то способом задать MouseX/Y тоисть двигать курсор мышки програмно?

[dimarik]

"has not yet been initialized" - Результатов: примерно 455 000
"has not been initialized yet" - Результатов: примерно 127 000

Добавлено через 2 минуты

Сообщение от wolhw

И есче вопрос касающийся мыши-- можно ли каким то способом задать MouseX/Y тоисть двигать курсор мышки програмно?

Еще, каким-то, то есть, программно.

Нет, нельзя.