Хорошее MVC - Страница 57

Akopalipsis · 30.09.2013, 02:07

Dukobpa3 Спасибо Вам за помощь!
я удалил предыдущий код, добавил изменённый + новый класс -...

Цитата:

думаю когда будет больше - появятся еще вопросы.

Так и есть, я просто сначала убедиться хочу, что самое минимальное понимаю, а потом уже продвигаться к тому, что я вообще не знаю как сделать. По этому ушёл делать пример дальше, чтобы Вам понятней было.

Код AS3:

package 
{
	import flash.display.Sprite;
 
	public class Main extends Sprite 
	{
 
		public function Main() 
		{
			new BaseController(this);
		}
 
	}
 
}

Код AS3:

package 
{
	import flash.display.DisplayObjectContainer;
	import flash.events.DataEvent;
 
	public class BaseController 
	{
		private var _doc:DisplayObjectContainer;
 
		private var _model:Model;
		private var _view:View;
 
		private var _storageObject:Object =
		{
 
		}
 
		public function BaseController($doc:DisplayObjectContainer) 
		{
			super();
 
			_doc = $doc;
 
			_model = new Model();
			_model.DOCSize = [_doc.root.parent.stage.stageWidth, _doc.root.parent.stage.stageHeight];
			trace(_doc.root.parent)
			_view = new View(_model);
			_view.addEventListener('MENU', view_viewClickHandler);
 
			_doc.addChild(_view);
		}
 
		private function view_viewClickHandler(event:DataEvent):void 
		{
			_model.accessStatus(event.data);
		}
 
	}
 
}

Код AS3:

package 
{
	import adobe.utils.CustomActions;
	import flash.events.Event;
	import flash.events.EventDispatcher;
 
	public class Model extends EventDispatcher implements IModel 
	{
		private var _DOCSize:Array = [];
		private var _getColor:uint ;
 
		private var _menuStatus:String;
 
		public function Model()
		{
			super();
 
		}
		public function accessStatus($button:String):void
		{
			if ($button == '0')
			{
				if (_menuStatus == $button) return;
				_menuStatus = $button;trace(';;;;;;;;;;;')
				_getColor = 0xA8F2ED;
				dispatchEvent(new Event('MODEL_MENU'));
			}
			else
			if ($button == '1')
			{
				if (_menuStatus == $button) return;
				_menuStatus = $button;
				_getColor = 0xEBF2A8;
				dispatchEvent(new Event('MODEL_MENU'));
			}
			else
			if ($button == '2')
			{
				return;
			}
			else
			{
				throw new Error('ERROR');
			}
		}
 
		public function get DOCSize():Array 
		{
			return _DOCSize;
		}
 
		public function set DOCSize(value:Array):void 
		{
			_DOCSize = value;
		}
 
		public function get getColor():uint 
		{
			return _getColor;
		}
 
		public function set getColor(value:uint):void 
		{
			_getColor = value;
		}
 
	}
 
}

Код AS3:

package 
{
	import flash.events.IEventDispatcher;
 
	public interface IModel extends IEventDispatcher
	{
		function accessStatus($button:String):void;
		function get DOCSize():Array; 
		function get getColor():uint ;
	}
 
}

Код AS3:

package 
{
	import flash.display.Sprite;
	import flash.events.DataEvent;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	public class View extends Sprite 
	{
		private var _model:IModel;
 
		private var _button:Button;
		private var _menuContainer:Sprite;
		private var _backgraund:Sprite;
 
		public function View($model:IModel) 
		{
			super();
 
			this.mouseEnabled = false;
 
			_model = $model;
			_model.addEventListener('MODEL_MENU', model_modelMenuHandler);
 
			_backgraund = new Sprite();
			_backgraund.mouseChildren = false;
			_backgraund.mouseEnabled = false;
			_backgraund.graphics.beginFill(0xF7E1D5);
			_backgraund.graphics.drawRect(0, 0, _model.DOCSize[0], _model.DOCSize[1]);
			_backgraund.graphics.endFill();
			super.addChild(_backgraund);
 
 
			this.addEventListener(MouseEvent.MOUSE_DOWN, this_mouseDownHandler);
 
 
			var id:int = 0;
			_menuContainer = new Sprite();
			_menuContainer.name = 'menu';
			super.addChild(_menuContainer);
 
			for (var i:int = 0; i < 3; i++) 
			{
				_button = new Button();
				_button.id = id++;
				_button.x += 72 * i;
				_menuContainer.addChild(_button);
			}
 
 
		}
 
		private function model_modelMenuHandler(event:Event):void 
		{
			_backgraund.graphics.clear();
			_backgraund.graphics.beginFill(uint(_model.getColor));
			_backgraund.graphics.drawRect(0, 0, _model.DOCSize[0], _model.DOCSize[1]);
			_backgraund.graphics.endFill();
		}
 
		private function this_mouseDownHandler(event:MouseEvent):void 
		{
			super.dispatchEvent(new DataEvent('MENU',false,false,event.target.id));
		}
 
	}
 
}

Код AS3:

package 
{
	import flash.display.Sprite;
 
	public class Button extends Sprite 
	{
		private var _id:int;
 
		public function Button() 
		{
			this.graphics.beginFill(0xA9B6F1);
			this.graphics.drawRect(0, 0, 70, 45);
			this.graphics.endFill();
		}
 
		public function get id():int 
		{
			return _id;
		}
 
		public function set id(value:int):void 
		{
			_id = value;
		}
 
	}
 
}

in4core · [+4 06.05.14]

Цитата:

_model.DOCSize = [_doc.root.parent.stage.stageWidth, _doc.root.parent.stage.stageHeight];

_model.DOCSize = [_doc.stage.stageWidth, _doc.stage.stageHeight];

Цитата:

_view.addEventListener('MENU', view_viewClickHandler);

Тут лучше делать кастом, типа ViewEvents - это хорошая практика. Так же стоит называть константы логично, например MENU_CLICK_EVENT!!

Цитата:

$button:String)

Аналогично - называйте логично, кнопка не может быть строкой, сам же потом запутаетесь. В моделе так же создать кастом ModelEvents - И делать адекватные имена MODEL_CUSTOM_EVENT.

А вот с интерфейсами спешить не надо, просто так шмалять ими не стоит, лучше на первых порах и в небольших проектах их не использовать, толку они вам не сделают, только мозг засорят на начальной стадии. В любом случае со временем вы сами начнете понимать когда они действительно пригодятся.

Цитата:

public function View($model:IModel)

Я бы посоветовал привыкать к
view.model = someModel. То есть к сеттерам , а не передаче в конструктор. Потому, что если моделей надо будет больше пихать их в конструктор, ну не очень красиво, да и на момент создания конструктора они могут быть Null.

Код AS3:

super.dispatchEvent(new DataEvent('MENU',false,false,event.target.id));

Нужно так :

Код AS3:

dispatchEvent(new DataEvent(DataEvent.MENU_CUSTOM_EVENT, target.id));

Добавлено через 2 минуты
Ну и наконец, зачем вам все это надо то? Что вы хотите получить? Какое то приложение делаете или что? Если свой сайт решили писать, я могу показать, как это будет в MVC эквиваленте, конечно не идеально, но похожеее на правду

Akopalipsis · 30.09.2013, 22:08

in4core Спасибо за учение, я естественно всё учел и ещё у меня есть один вопрос - вот там где Вы писали про кнопку, что она не может быть строкой... я вчера когда делал события, то первым делом вспомнил, что желательнее использовать события нативные, так как такая практика в будущем поможет делать легко переносимые модули. Но когда я дошел до кода с кнопкой, то сразу пришёл к выводу, что лучше сделать свое событие, куда добавить пункт самого обьекта-target и уже полноценно считывать его id. И ещё одним аргументом в пользу собственного события было сообщение, когда говорили, что вот по таким строковым сравнениям, как раз можно попасть в неприятную ситуацию. По этому - как лучше делать, нативными сообщениями со строкой или собственное событие с передачей target?

Цитата:

Ну и наконец, зачем вам все это надо то? Что вы хотите получить?

Получить я хочу умение писать код по шаблону MVC так, чтобы не один человек не смог сказать что там что то не так. По этому я учась и не куда не спеша, начал с самого минимального и со временем буду наращивать обороты и ждать одобрения. И я бы не отказался посмотреть реализацию чего то.

in4core · [+4 06.05.14]

Цитата:

Получить я хочу умение писать код по шаблону MVC так, чтобы не один человек не смог сказать что там что то не так. По этому я учась и не куда не спеша, начал с самого минимального и со временем буду наращивать обороты и ждать одобрения. И я бы не отказался посмотреть реализацию чего то.

Всегда, кто нибудь да что то скажет - это интернет. Не бывает хорошего МВС, вот с чего надо начинать. Бывают разные реализации.
Кто вам сказал что нативные события лучше испольщовать чем кастомные? Ничего подобного - делать надо так, как удобоваримо и располагает ситуация. Чтобы ответь на вопрос передачи таргета,строк или еще чего, надо сначала сформулировать задачу, типа хочу чтобы по клику на меню создавался модуль Б и т.п. Тогда вам подскажут - а пока говорить неочем

Akopalipsis · 26.10.2013, 01:21

Не знаю когда закралась ко мне в голову эта мысль, но точно знаю, когда я решил, что её уже не оставлю без внимания - этот момент наступил после этого поста. Но я не думал, что у меня появится ещё одна мысль, которая побудит меня на столь раннее задание этого вопроса.
Вот все говорят, что вью не имеет ссылки на контроллер ( и как считаю я, только по этому не рассматривают ПЛЮСЫ от этого ), но если немного отдалится от этого и забыть о EventDispatcher, то как бы она могла передать массив данных требуемые в модели? Или вью, которая посылая события EventDispatcher ( по сути калбеки ), разве не имеет ссылку на контроллер? Ведь это одно и тоже... В чем я не прав?
И хоть застрелите, но я тоже подсел на эту тему, не могу не чего с собой поделать))

Psycho Tiger · 26.10.2013, 13:56

Вью имеет ссылку на контроллер на уровне приложения, но не на уровне кода, с которым ты работаешь.
Ядро может быть сколь-угодно-криво-написанное, но если оно имеет хорошее API и достаточный функционал – тебе никогда не придется лезть в это ядро, а сам ты сможешь писать хороший код, который легко поддерживать.

Wolsh · 05.11.2013, 15:38

Что лично мне не нравится в событиях от Вью к Контроллеру?
Это вобщем-то отлично, когда ничего кроме типа События не требуется.
Но как только возникает ситуация, когда необходимо передавать данные, весь смысл меняется.
Становятся необходимы особые кастомные классы Событий-контейнеров данных. Эти классы должны знать (то есть иметь с ними жесткую связанность) и Вью и Контроллер. Я уже как-то "наезжал" на такую же проблему с событиями от Модели к Вью, и здесь ситуация ничем не лучше. Разруливать ее с помощью неких "интерфейсов событий" имхо маразм, особенно когда напрягает само количество новых классов-Событий, каждый из которых нужен для поддержки одного единственного действия юзера во Вью/изменения данных в Модели — так к каждому еще и Интерфейс заводить?
Я к тому, что в ситуации неявной жесткой связанности через события говорить об идеалах независимости фигурантов MVC довольно лицемерно, а учитывая сильную физическую/логическую связь между Вью и Контроллером (второй, по сути, придаток Вью), я лично вполне допускаю схему с прямой ссылкой и прямым вызовом методов контроллера из вью-хозяина. "Передать массив" в такой ситуации не потребует ни нового Класса События, ни Интерфейса для него, а связанность, по сути, та же самая. Реальную независимость имеет только Модель, и ей ничто не угрожает.

Котяра · 05.11.2013, 15:52

Если вместо контроллера использовать PM (Presentation Model)
То именно так там и делается.
http://www.martinfowler.com/eaaDev/P...tionModel.html
http://blogs.adobe.com/paulw/archive...tion_pa_3.html
http://examples.pmwilliams.co.uk/ado...iew/index.html
http://examples.pmwilliams.co.uk/ado...ss-diagram.jpg

lammer.Ok · 01.02.2014, 04:02

Подскажите и мне в вопросе. При загрузке программы, кто грузит все необходимые картинки и тд. для UI? Например, у меня готовится редактор, и мне необходимо подготовить и загрузить много картинок для тулбара. Кто этим занимается из mvc или эту функцию выполняет совершенно левый класс, какой-нибудь UILoader ?

Dukobpa3 · 01.02.2014, 05:10

Менеджмент ресурсов не входит в задачи модели.

Менеджмент ресурсов так же не входит и в задачи контроллера.

Методом исключения приходим к тому что картинки должны быть во вью(ну и очевидно что она ведь их отображает). А откуда вью их возьмет - уже ваша задача придумать.
И вьюха например сама должна знать что для статуса модели "вкл", она должна отобразить картинку "зеленая_галочка.жпг".
Вью может ссылку на эту галочку взять из отдельной какой-то модели-конфига со словарем урлов по иду или готовую картинку из какой-то фабрики.