фотографии с гугла и bitmap.draw

[iflamberg]

привет.
заказчик попросил сделать 3д-галерею. Я взял бесплатную галерею на papervision3d, изменил ее под свои нужды. Все работает, фотографии загружаются из xml файла. Проблемы начались, когда оказалось, что фотографии надо загружать не из домена заказчика, а с гугла. Я немного расслабился, когда оказалось, что у гугла есть crossdomain.xml, который разрешает загружать фото (см. http://mw2.google.com/crossdomain.xml).
Но вдруг открылась проблема: простая тестовая программа загружала фотки, а галерея нет. После некоторого изучения, оказалось, что pv3d повсеместно использует битмапу(вполне естественно), и есть проблема: если фотография загружена с чужого домена, то сделать из нее битмапу нельзя, ругается:

Нарушение изолированной среды: BitmapData.draw: http://localhost/gal3d/flash.swf не может осуществить доступ к http://mw2.google.com/mw-panoramio/photos/medium/5738675.jpg. Не предоставлен доступ к файлам политики.

простой тестовый код:

package {
	import flash.display.*;
	import flash.events.*;
	import flash.net.URLRequest;
	import flash.system.*;
	import flash.display.*;
	
	public class Test extends MovieClip {
		var loader:Loader;

		function Test () {
			loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onPicLoaded);
			var lc:LoaderContext = new LoaderContext(); lc.checkPolicyFile = true;
			loader.load(new URLRequest("http://mw2.google.com/mw-panoramio/photos/medium/5738675.jpg"),lc);
			//loader.load(new URLRequest("http://mw2.google.com/mw-panoramio/photos/medium/5738675.jpg"));
		}
	
		function onPicLoaded (e:Event) {
			addChild(loader); //так можно
			/*
			var bitmap:BitmapData = new BitmapData(loader.width, loader.height, true);
			bitmap.draw (loader);
			var b:Bitmap = new Bitmap(bitmap);
			addChild (b);
			///*///   а так нельзя!!!
		}
	}
}

дальнейшее изучение показало, что нужен особый файл политики, чтобы редактировать загруженные битмапдаты. Такой файл политики есть у flikr, например. http://static.flickr.com/crossdomain.xml.
Положил к себе на тестовый сервер эту xml-ку и тестовый код без проблем загрузил и превратил в битмапу картинку http://gamesworker.com/1.jpg .
Кто-нибудь с таким сталкивался? Как-нибудь обойти можно?

[wvxvw]

Файл политик, который вы забираете у Гугла - это мастер, вся информация, которая в нем есть - это то, что другие файлы политик с этого сервера выдаются только по протоколу HTTP/HTTPS, контент-тайп "Content-Type: text/x-cross-domain-policy". Это значит, что, наверняка на этом же сервере есть и другие файлы политик безопасности (они разрешены), но откуда их загружать - неизвестно (возможно, для этого нужен аккаунт в Гугле или что-то в этом роде). Но сам по-себе этот файл вам разрешения на использование картинок или другого контента вам не дает.

[iflamberg]

Я не смог найти эти файлы безопасности только тот, ссылку на который привел, в корне. Но фотографии загружаются, значит флеш берет где-то правильный crossdomain.xml . Но работать с битмапой нельзя.

Такая проблема действительно существует:
http://livedocs.adobe.com/flash/8/ma...=00001950.html (смотреть в коментариях)
или вот
http://www.untoldentertainment.com/blog/?p=24

а у фликра все работает.
похоже без прокси не обойтись

[wvxvw]

Прочитайте еще раз... сравните файл политик, который отдает фликр и гугл - не замечаете разницы? Гугл вам не дает никакого разрешения на использование чего бы то ни было с их домена кроме файлов политик, а фликр разрешает любому домейну загружать что угодно.
Флешу не нужны файлы политик чтобы загружать картинки, они нужны для доступа к битмапдате.

[etc]

Можно провернуть такой чит:

package {
	import flash.display.*;
	import flash.events.*;
	import flash.net.*;
	import flash.system.*;
	import flash.display.*;
 
	public class Test extends MovieClip {
		var loader:Loader;
 
		function Test () {
			loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onPicLoaded);
			var lc:LoaderContext = new LoaderContext();
			lc.checkPolicyFile = true;
			loader.load(new URLRequest("http://mw2.google.com/mw-panoramio/photos/medium/5738675.jpg"),lc);
			//loader.load(new URLRequest("http://mw2.google.com/mw-panoramio/photos/medium/5738675.jpg"));
		}
 
		function onPicLoaded (e:Event) {
			this.loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onPicLoaded);
			this.loader.contentLoaderInfo.addEventListener(Event.COMPLETE, this.handler_complete);
			this.loader.loadBytes(this.loader.contentLoaderInfo.bytes, new LoaderContext(false, ApplicationDomain.currentDomain));
		}
 
		private function handler_complete(event:Event):void {
			var bitmap:BitmapData = new BitmapData(loader.width, loader.height, true);
			bitmap.draw (loader);
			var b:Bitmap = new Bitmap(bitmap);
			super.addChild (b);
		}
	}
}

[wvxvw]

И не будет ошибки когда this.loader.contentLoaderInfo.bytes? В 9-м и в 10-м плеере? Если так, то это скорее всего баг....

[etc]

Не будет
Это дырка, в общем-то.

[Яски]

__etc, я фигею если твой код работает. Адобе для чего вообще спрашивается эти политики безопасности придумала, если для их обхода не надо даже ничего стороннего и сложного использовать.

[etc]

Ну, я к себе на сайт флешку залил, она работает.

[iflamberg]

2etc: а чем вы компилируете этот код? Под какой flash player? У меня он не компилируется, ругается на

Access of possibly undefined property bytes through a reference with static type flash.display:LoaderInfo

ну, т.е. у LoaderInfo нет свойства bytes. И в хелпе я не могу его найти. А вот код я пишу в FlashDevelop и он такое свойтсво у LoaderInfo знает =/
у меня CS3.


а, все, нашел ответ: http://www.flasher.ru/forum/archive/.../t-110427.html