Проблема "загрязнения" сцены

[TonKhaO]

Народ тема названиа весьма необычно но другого названия подорбрать не мог )))
прилагаю исходник ))) суть в том что через минут 5 ато и раньше кол-во снежинос достигнем апофиозного состояния и флеш вместе с компом будут тормозить, что нужно в коде подправить чтобы он удалял каждый раз лишние обьекты когда баннер начинает прокручиваться заново?

Добавлено через 1 минуту
загрузить аттач не смог вот собсно код который в первом кадре баннера

Stage.scaleMode = "noScale";
_root._quality = "BEST";
//Создаём переменные ,которые будут влиять на движение снежинок, своеобразный
//ВЕТЕР (по оси X) и ПРИТЯЖЕНИЕ (по оси Y)
//Это ветер (ускорение по оси X)
var dX:Number = 0;
//Это притяжение/гравитация (по оси Y);
var dY:Number = 0.25;
//Функция, которая будет периодически менять значение "СИЛЫ ВЕТРА".
function glob_func() {
	//Создаём переменную, значение которой будет варьироваться от -1 до +1
	//Это у нас будет новое значение ускорения по оси X (ветер)
	_root.newX = Math.random()*1-Math.random()*1;
	//Вычисляем ШАГ, за который будет изменяться прошлое значение ВЕТРА, на новое
	//значение. Делаем это для того, чтобы смена происходила не рывком, а плавно.
	_root.chX = (_root.newX-_root.dX)/(50+random(50));
	//На всякий случай удаляем старый интервал, если переход старого значения в 
	//новое ещё не успел закончиться.
	clearInterval(_root.x_int);
	//Запускаем новый интервал, который будет каждые 30 миллисекунд вызывать 
	//функцию, прибавляющую к старому значению слиы ВЕТРА, значение ШАГА, который
	//мы вычислили немного выше.
	_root.x_int = setInterval(function () {
		//Прибавляем к старому значению значение шага
		_root.dX += _root.chX;
		//Проверяем, если текущее значение скорости вестра приближённое до десятых
		//равно новому значению силы вытера, так же приближённому до десятых,
		//то переход старого значения силы ветра в новое уже закончился, а значит
		//можно удалять интервал вызывающий эту функцию.
		if (Math.round(_root.dX*10)/10 == Math.round(_root.newX*10)/10) {
			clearInterval(_root.x_int);
		}
	}, 30);
}
//Создаём интервал, который будет вызывать функцию изменения СИЛЫ ВЕТРА один
//раз в 5 секунд.
setInterval(glob_func, 5000);
//Создаём функцию движения снежинок
function move_func() {
	//Чем меньше снежинка, тем дальше она от нас находится, чем она дальше от нас
	//находится, тем менее заметны нам изменения в её положении. Другими словами
	//если объект (снежинка) стоящий от нас на рсстоянии 1 метра переместить на 
	//5 метров вправо, то мы это увидим точно. А если этот же обхект будет
	//находиться от нас на расстоянии 100 метров, то перемещения на 5 метров,
	//мы, возможно, ине заметим уже.
	//
	//varDif - это переменная, которая будет влиять на изменение положения
	//снежинки, таким образом, что чем снежинка меньше, тем медленней её положение
	//будет изменяться.
	varDif = this._xscale/100;
	//Прибавляем к текущей координате _x переменную скорости снежинки, и,
	//изменённую на значение varDif СИЛУ ВЕТРА
	this._x += this.dX+_root.dX*varDif;
	//Аналогично СИЛЕ ВЕТРА выше
	this._y += this.dY+_root.dY*varDif;
	//Если снежинка ушла за ниднюю границу флешки ,то мы удаляем эту снежинку.
	if (this._y>=Stage.height) {
		this.removeMovieClip();
	}
}
//Функция, которая будет периодически создавать новые снежинки.
function snow_func() {
	//Подключаем на глдавную сцену из библиотеки экземпляр снежинки.
	//По оси _y снежинка будет стоять на 30 px выше верхнего края флешки.
	//По оси _x занчение может быть от -75 до ШИРИНА_ФЛЕШКИ + 75, т.е. созданная
	//снежинка может выходить за края флешки по оси _x
	varTarget = _root.attachMovie("snow_mc", "snow"+_root.getNextHighestDepth()+"_mc", _root.getNextHighestDepth(), {_y:-30, _x:-75+Math.random()*(Stage.width+75)});
	//Опредеяем размер снежинки, который будет варьироваться от 25% исходного
	//размера, до 100%
	varTarget._xscale = varTarget._yscale=25+Math.random()*75;
	//Определяем значение собственной скорости снежинки по оси _x. Оно будет
	//варьироваться от -1 до +1
	varTarget.dX = Math.random()*1-Math.random()*1;
	//Определяем скорость падения снежинки. Скоростьпадения будет зависеть от
	//размера снежинки, но никогда не будет меньше 0.5
	varTarget.dY = 0.5+varTarget._xscale/100;
	//Каждый раз при смене кадра, для снежинки будет вызываться функция move_func
	varTarget.onEnterFrame = _root.move_func;
}
//Создаём интервал, вызывающий функцию СОЗДАНИЯ СНЕЖИНОК раз в 75 миллисекунд.
setInterval(snow_func, 75);
//
logo_mc.onRollOver = function() {
};

Добавлено через 26 минут
попробовал в конце интервал увеличить но это лишь не надолго помогло, нужно как то "убить" функцию после достижения конца баннера, помогите плиззз

[iflamberg]

код очень чистый и аккуратный, запустил у себя - не вижу никаких проблем. Снежинки, как и прописано в коде удаляются, когда достигнут нижней границы сцены. ЦП показывает примерно одинаковую загрузку, оперативная память тоже.

в том коде, что вы предоставили - ошибок нет, имо. Ищите где-то еще.

[Zik.]

Так все хорошо, все работает
Но было бы неплохо добавить после этой строчки

this.removeMovieClip();

написать, чтобы ентерфреймы тоже удалялись

delete this.onEnterFrame;

[iflamberg]

в as2 onEnterFrame не отрабатывает, если мувик удален со сцены.

[AlexCooper]

не вижу исходника

Добавлено через 7 минут
Я думаю возможно что это связанно из-за большой глубины мувика. Поменяйте

_root.getNextHighestDepth()

Добавлено через 10 минут
на проверку занятости глубины начиная с нуля. Да еще можно разгрузить постоянный поиск свободной глубины предварительно про сканировав свободных ~100 глубин, загнать в массив, а лучше в объект и крутить по кругу

Добавлено через 15 минут
или же проататчить 100 снежинок и при достижении их крайней нижней бросать на верх перерандомив свойства

[TonKhaO]

а может влият то что у меня как бы флеш ролик состоит не из 1 собственно кадра, а у меня то есть на главной сцене есть примерно 200 кадров и некоторая анимация которая как бы идет под снег, может ли быть в это загвоздка

Добавлено через 4 минуты
вот что в коде

//Каждый раз при смене кадра, для снежинки будет вызываться функция move_func
	varTarget.onEnterFrame = _root.move_func;

может именно в этом дело ?

Добавлено через 9 минут

Сообщение от AlexCooper

не вижу исходника

вот он http://shinoda.ru/ny.fla, попробуйте оставить минут на 10 флешик и увидите результат

[iflamberg]

да, блин. Всегда конвертируйте в cs3, знаете не все пиратками пользуются.

[TonKhaO]

Сообщение от iflamberg

конвертируйте в cs3.

перезалил