нестандартная форма флэш

[bo0bon]

Здравствуйте уважаемые форумчани. Я не знал как правильно назвать тему, поэтому если будет более подходящее название - переименуйте пожалуйста.

У меня есть скрипт, который выводит на форме снег. Он общедоступный, я лишь добавил к нему переменную, которая ограничивает количество снежинок. Вот он:

Stage.scaleMode = "noScale";
_root._quality = "BEST";
//Создаём переменные ,которые будут влиять на движение снежинок, своеобразный
//ВЕТЕР (по оси X) и ПРИТЯЖЕНИЕ (по оси Y)
//Это ветер (ускорение по оси X)
var dX:Number = 0;
//Это притяжение/гравитация (по оси Y);
var dY:Number = 0.25;
var zozo:Number = 0;
//Функция, которая будет периодически менять значение "СИЛЫ ВЕТРА".
function glob_func() {
	//Создаём переменную, значение которой будет варьироваться от -1 до +1
	//Это у нас будет новое значение ускорения по оси X (ветер)
	_root.newX = Math.random()*1-Math.random()*1;
	//Вычисляем ШАГ, за который будет изменяться прошлое значение ВЕТРА, на новое
	//значение. Делаем это для того, чтобы смена происходила не рывком, а плавно.
	_root.chX = (_root.newX-_root.dX)/(50+random(50));
	//На всякий случай удаляем старый интервал, если переход старого значения в 
	//новое ещё не успел закончиться.
	clearInterval(_root.x_int);
	//Запускаем новый интервал, который будет каждые 30 миллисекунд вызывать 
	//функцию, прибавляющую к старому значению слиы ВЕТРА, значение ШАГА, который
	//мы вычислили немного выше.
	_root.x_int = setInterval(function () {
		//Прибавляем к старому значению значение шага
		_root.dX += _root.chX;
		//Проверяем, если текущее значение скорости вестра приближённое до десятых
		//равно новому значению силы вытера, так же приближённому до десятых,
		//то переход старого значения силы ветра в новое уже закончился, а значит
		//можно удалять интервал вызывающий эту функцию.
		if (Math.round(_root.dX*10)/10 == Math.round(_root.newX*10)/10) {
			clearInterval(_root.x_int);
		}
	}, 30);
}
//Создаём интервал, который будет вызывать функцию изменения СИЛЫ ВЕТРА один
//раз в 5 секунд.
setInterval(glob_func, 5000);
//Создаём функцию движения снежинок
function move_func() {
	//Чем меньше снежинка, тем дальше она от нас находится, чем она дальше от нас
	//находится, тем менее заметны нам изменения в её положении. Другими словами
	//если объект (снежинка) стоящий от нас на рсстоянии 1 метра переместить на 
	//5 метров вправо, то мы это увидим точно. А если этот же обхект будет
	//находиться от нас на расстоянии 100 метров, то перемещения на 5 метров,
	//мы, возможно, ине заметим уже.
	//
	//varDif - это переменная, которая будет влиять на изменение положения
	//снежинки, таким образом, что чем снежинка меньше, тем медленней её положение
	//будет изменяться.
	varDif = this._xscale/100;
	//Прибавляем к текущей координате _x переменную скорости снежинки, и,
	//изменённую на значение varDif СИЛУ ВЕТРА
	this._x += this.dX+_root.dX*varDif;
	//Аналогично СИЛЕ ВЕТРА выше
	this._y += this.dY+_root.dY*varDif;
	//Если снежинка ушла за ниднюю границу флешки ,то мы удаляем эту снежинку.
	//if (this._y>=Stage.height) {
	if (this._y>=Stage.height+this._height) {
		this.removeMovieClip();
		zozo--;
	}
}
//Функция, которая будет периодически создавать новые снежинки.
function snow_func() {
	//Подключаем на глдавную сцену из библиотеки экземпляр снежинки.
	//По оси _y снежинка будет стоять на 30 px выше верхнего края флешки.
	//По оси _x занчение может быть от -75 до ШИРИНА_ФЛЕШКИ + 75, т.е. созданная
	//снежинка может выходить за края флешки по оси _x
	if (zozo<100) {
	varTarget = _root.attachMovie("snow_mc", "snow"+_root.getNextHighestDepth()+"_mc", _root.getNextHighestDepth(), {_y:-30, _x:-75+Math.random()*(Stage.width+75)});
	//Опредеяем размер снежинки, который будет варьироваться от 25% исходного
	//размера, до 100%
	varTarget._xscale = varTarget._yscale=25+Math.random()*75;
	//Определяем значение собственной скорости снежинки по оси _x. Оно будет
	//варьироваться от -1 до +1
	varTarget.dX = Math.random()*1-Math.random()*1;
	//Определяем скорость падения снежинки. Скоростьпадения будет зависеть от
	//размера снежинки, но никогда не будет меньше 0.5
	varTarget.dY = 0.5+varTarget._xscale/100;
	//Каждый раз при смене кадра, для снежинки будет вызываться функция move_func
	varTarget.onEnterFrame = _root.move_func;
	zozo++;
		}
}
 
//Создаём интервал, вызывающий функцию СОЗДАНИЯ СНЕЖИНОК раз в 75 миллисекунд.
setInterval(snow_func, 75);
//
logo_mc.onRollOver = function() {
};

проблема в том, что со временем, когда снежинок становится достаточно много, получается не очень красиво, так как становится видно границы флешки:


возникла идея сделать форму флешки нестандартной, но поиск не дал результатов.
далее я подумал, что можно создать отдельный movieClip, обазначить в нем границы, например карандашом:


которые будут обозначать что при достижении этих границ снежинку нужно уничтожать, и запускать скрипт вывода снега в нем. но знаний для этого не хватило. поэтому прошу помощи у знающих людей хотя-бы где об этом можно почитать. заранее благодарю за ответы!

[GBee]

Маска + maxX, maxY?

[iNils]

Вам нужна маска, почитайте про setMask.