Проверка времени

[Партизан]

Сообщение от TEI

Мне нужно время не с момента запуска игры, а глобальное время. 22.12.2016 21:33

Вам уже кучу постов с вариантами решения через getTimer() написали. В документации по Date() от Adobe так же рекомендуют использование getTimer()

Чтобы вычислить относительное или прошедшее время, воспользуйтесь методом getTimer() из пакета flash.utils.

Если этого мало для вашей задачи, оставьте как есть. Единственное, рекомендую принудительно удалять созданный экземпляр Date.

[faraday]

Еще для проврки времени, нужно по каждому завершению таймера делать синхронизацию времени с сервером. у некоторых игроков за час время клиента расходится с сервером на 5 и больше минут, причина так и не обнаружена

[Tails]

package pocket.clock
{
	import flash.utils.getTimer;
 
	/**
	 * Игровые часы.
	 * Содержит текущее время, которое берётся из системы пользователя.
	 * Можно синхронизировать часы, указав собственное текущее время.
	 * @author Roman A.V.
	 */
	public class Clock
	{
 
		// Приват
		private var _runDate:Number;
 
		/**
		 * Создать часы.
		 * Текущее время берётся из системы пользователя.
		 */
		public function Clock()
		{
 
			// Инициализация.
			// Получаем системное время:
			_runDate = new Date().time;
 
			// Вычитаем уже прошедшее время, так-как используем дату как точку отсчёта:
			_runDate -= getTimer();
 
			// Не может быть NaN или меньше 0:
			if (isNaN(_runDate) || _runDate < 0)
				_runDate = 0;
		}
 
		// ПАБЛИК
		/**
		 * Синхронизировать текущее время.
		 * Передайте текущее время, если требуется синхронизировать часы.
		 * Этот вызов также изменит значение переменной <code>runDate</code>.
		 * @param	time Миллисекунды, прошедшие с 1 января 1970 года.
		 */
		public function setCurrentTime(time:Number):void
		{
			_runDate = time - getTimer();
 
			// Не может быть NaN или меньше 0:
			if (isNaN(_runDate) || _runDate < 0)
				_runDate = 0;
		}
 
		// ГЕТТЕРЫ
		/**
		 * Дата запуска приложения. (mc)
		 * Указывает дату, когда было запущено текущее приложение.
		 * Миллисекунды, прошедшие с 1 января 1970 года.
		 * Не может быть NaN или меньше 0.
		 */
		public function get runDate():Number
		{
			return _runDate;
		}
 
		/**
		 * Текущее время. (mc)
		 * Возвращает количество миллисекунд, прошедших на момент вызова с 1 января 1970 года.
		 * Не может быть NaN.
		 */
		public function get currentTime():Number
		{
			return _runDate + getTimer();
		}
	}
}

[faraday]

Tails, ты не наблюдал рассинхрон времени? использую аналогичный код, и постоянно ловлю репорты что несовпадает с сервом, при пинге меньше секунды

[Tails]

faraday
Нет, не наблюдал. Какого рода рассинхрон? Разница постепенно накапливается или фиксированная с самого начала?

[faraday]

постепенно, когда расхждение больше 10 секунд - синхронизирует с сервом, и через пару минут рассинхрон опять. бывает где-то у 5% игроков, на протяжении всей сессии

[caseyryan]

Сообщение от faraday

постепенно, когда расхждение больше 10 секунд - синхронизирует с сервом, и через пару минут рассинхрон опять. бывает где-то у 5% игроков, на протяжении всей сессии

Может у них дико тормозит все?
Хотя, сдается мне, ошибка в коде

[faraday]

Врядли в таком коде может быть ошибка. расхождения дает как getTimer, так и new Date().getTime(), сетер добавлен как вынужденая мера именно из-за постоянных расхождений, так больше не что не влияет. приходится добавлять время в каждый ответ сервера, и синхронизировать каждый таймер в момент инициализации и завершения. геморой на ровном месте

	public static function init(time:int) {
			serverTime = time;
			timer.start();
			timer.addEventListener(TimerEvent.TIMER, updateTime);
		}
		private static function updateTime(t:TimerEvent = null) {
			_now = elapse + timeDiff; 
			dispatchEventWith(Clock.TICK, false, serverTime);
		}
		public static function set serverTime(time:int):void{
			timeDiff = time - elapse;
			updateTime();
		}
		public static function get serverTime():int{
			return _now;
		}	
		static public function get elapse():int 
		{
			return Math.floor(getTimer() / 1000);
		}

[Партизан]

Сообщение от faraday

Врядли в таком коде может быть ошибка.

Думаю если округлять до 5 секунд расхождение будет еще больше...

[undefined]

Может у них дико тормозит все?

тогда бы у них и часы отставали.Вообще вроде как часы зависят только от батарейки на материнке и тормозить не могут по определению.